diff --git a/js17/PKGBUILD b/js17/PKGBUILD
new file mode 100644
index 000000000..31368d7fd
--- /dev/null
+++ b/js17/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer:  Ram-Z <samir.benmendil[at]gmail[dot]com>
+# Contributor: Ionut Biru <ibiru@archlinux.org>
+
+pkgname=js17
+pkgver=17.0.0
+pkgrel=2
+pkgdesc="JavaScript interpreter and libraries (legacy)"
+arch=(x86_64)
+url="https://developer.mozilla.org/En/SpiderMonkey/17"
+license=(MPL)
+depends=(nspr gcc-libs readline)
+makedepends=(python2 zip libffi)
+conflicts=('js<24.2.0')
+options=(!staticlibs)
+source=(http://ftp.mozilla.org/pub/mozilla.org/js/mozjs$pkgver.tar.gz)
+md5sums=('20b6f8f1140ef6e47daa3b16965c9202')
+
+build() {
+  unset CPPFLAGS
+  cd mozjs$pkgver/js/src
+
+  ./configure \
+    --prefix=/usr \
+    --with-system-nspr \
+    --with-system-ffi \
+    --enable-readline \
+    --enable-threadsafe
+
+  make
+}
+
+check() {
+  cd mozjs$pkgver/js/src
+  make check
+}
+
+package() {
+  cd mozjs$pkgver/js/src
+  make DESTDIR="$pkgdir" install
+  find "$pkgdir"/usr/{lib/pkgconfig,include} -type f -exec chmod -x {} +
+}
+
+