diff --git a/libu2f-host/PKGBUILD b/libu2f-host/PKGBUILD
new file mode 100644
index 000000000..f8071ca7b
--- /dev/null
+++ b/libu2f-host/PKGBUILD
@@ -0,0 +1,39 @@
+pkgname=libu2f-host
+pkgver=1.1.3
+pkgrel=1
+pkgdesc="Yubico Universal 2nd Factor (U2F) Host C Library"
+arch=('x86_64')
+url='https://github.com/Yubico/libu2f-host'
+license=('BSD')
+depends=('json-c' 'hidapi')
+makedepends=('git' 'help2man' 'gtk-doc' 'gengetopt')
+validpgpkeys=('0A3B0262BCA1705307D5FF06BCA00FD4B2168C0A'
+              'D459FCC2041AC8FEF297D53EB4AA8C689E629EAC')
+source=("https://developers.yubico.com/${pkgname}/Releases/${pkgname}-${pkgver}.tar.xz"{,.sig})
+sha256sums=('3e00c1910de64e2c90f20c05bb468b183ffed05e13cb340442d206014752039d'
+            'SKIP')
+
+build() {
+	cd "${pkgname}-${pkgver}"
+
+	./configure \
+		--prefix=/usr \
+		--enable-gtk-doc \
+		--with-udevrulesdir=/usr/lib/udev/rules.d/
+	make
+}
+
+
+check() {
+	cd "${pkgname}-${pkgver}"
+
+	make check
+}
+
+package() {
+	cd "${pkgname}-${pkgver}"
+
+	make DESTDIR="${pkgdir}/" install
+
+	install -D -m0644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
+}