Rebuild kdepim-runtime with text-to-speech support

flite/PKGBUILD

@@ -0,0 +1,37 @@
+# Fork from https://aur.archlinux.org/cgit/aur.git/plain/PKGBUILD?h=flite&id=ed18f1906aed8167ed5e7052a56ac1cdeb8e36e0
+
+pkgname=flite
+pkgver=2.0.0
+pkgrel=1
+pkgdesc="A lighweight speech synthesis engine (text to speech)"
+arch=('x86_64')
+url="http://cmuflite.org"
+license=('BSD')
+depends=('alsa-lib')
+options=('strip' '!buildflags')
+source=(http://festvox.org/flite/packed/flite-2.0/flite-2.0.0-release.tar.bz2)
+md5sums=('645db96ffc296cbb6d37f231cc1cc6b2')
+
+prepare() {
+  cd "${srcdir}/${pkgname}-${pkgver}-release"
+  sed '/^#VOXES.*$/d; s/+//g; s/cmu_indic_lex/&\nVOXES = cmu_us_kal16 cmu_us_slt/' config/android.lv > config/linux.lv
+  sed -i '/$(INSTALL) -m 755 $(BINDIR)\/flite_time $(DESTDIR)$(INSTALLBINDIR)/d' main/Makefile
+}
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}-release"
+  ./configure \
+    --prefix=/usr \
+    --enable-shared \
+    --with-audio=alsa \
+    --with-vox=cmu_us_kal16 \
+    --with-langvox=linux
+  make
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}-release"
+  make prefix="${pkgdir}/usr" install
+  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE" 
+}
+

kdepim-runtime/PKGBUILD

@@ -3,13 +3,13 @@ source ../kdeapps.conf
 
 pkgname=kdepim-runtime
 pkgver=${_kdever}
-pkgrel=2
+pkgrel=3
 pkgdesc='Extends the functionality of kdepim'
 arch=('x86_64')
 url='https://projects.kde.org/projects/kde/kdepim-runtime'
 license=('GPL' 'LGPL' 'FDL')
 depends=(hicolor-icon-theme libkgapi libkolab akonadi-socialutils akonadi-calendar
-         knotifyconfig kross kalarmcal kmbox kimap syndication)
+         knotifyconfig kross kalarmcal kmbox kimap qt5-speech syndication)
 makedepends=(extra-cmake-modules kdoctools boost)
 install=$pkgname.install
 options=('debug')

qt5-speech/PKGBUILD

@@ -0,0 +1,31 @@
+# Forked from: https://aur.archlinux.org/cgit/aur.git/plain/PKGBUILD?h=qtspeech-git&id=af3789be6b007d7c3403560af912d6fc194cd8ea
+
+pkgname=qt5-speech
+_pkgname=qtspeech
+pkgver=5.8.0
+_tag=v$pkgver-alpha1
+pkgrel=1
+pkgdesc="Qt Speech support."
+arch=('i686' 'x86_64')
+url="http://qt-project.org/wiki/QtSpeech"
+license=('GPL2' 'LGPL3' 'FDL')
+depends=('qt5-base' 'qt5-multimedia' 'speech-dispatcher')
+makedepends=('flite')
+optdepends=('flite: Speech output using Festival Lite.')
+source=("git+git://code.qt.io/qt/qtspeech.git#tag=$_tag")
+sha1sums=('SKIP')
+
+build() {
+  cd $_pkgname
+  qmake-qt5
+  make
+}
+
+package() {
+  make -C $_pkgname INSTALL_ROOT="${pkgdir}" install
+
+  # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
+  find "${pkgdir}/usr/lib" -type f -name '*.prl' -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;
+}
+
+