kde applications 18.08.0 Beta [skip-ci]

freecell-solver/PKGBUILD

@@ -0,0 +1,32 @@
+pkgname=freecell-solver
+pkgver=4.20.0
+pkgrel=1
+pkgdesc="A program that automatically solves layouts of Freecell and similar variants of Card Solitaire"
+arch=(x86_64)
+url="http://fc-solve.shlomifish.org"
+license=(MIT)
+depends=(bash)
+makedepends=(cmake gperf perl-path-tiny perl-template-toolkit python3-random2 python3-six)
+optdepends=('python3-random2: for the Python scripts' 'python3-six: for the Python scripts')
+source=(http://fc-solve.shlomifish.org/downloads/fc-solve/$pkgname-$pkgver.tar.xz)
+sha256sums=('869c210e7b63b0e0dcfb1c4a2322c41cfa8fbf8db01e7722254a7425a1ab7f81')
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DFCS_WITH_TEST_SUITE=OFF \
+    -DBUILD_STATIC_LIBRARY=OFF
+  make -j1
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+  install -Dm644 "$srcdir"/$pkgname-$pkgver/COPYING.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+

kdeapps.order

@@ -60,6 +60,9 @@
 #* okteta (moved to an independent release cycle)
 #* kholidays (moved to KDE Frameworks)
 
+# Info for 18.08.0 when lands to [stable]
+# remove libktnef
+
 
 chakra-common
 khelpcenter
@@ -249,7 +252,7 @@ kblog
 kdav
 kdepim-runtime
 kontactinterface
-libktnef
+ktnef
 calendarsupport
 eventviews
 incidenceeditor

kmail/PKGBUILD

@@ -8,7 +8,7 @@ arch=(x86_64)
 url="https://community.kde.org/KDE_PIM"
 license=(GPL2)
 depends=(kdepim-runtime kmail-account-wizard akonadi-import-wizard mbox-importer pim-sieve-editor
-         pim-data-exporter kontactinterface libktnef)
+         pim-data-exporter kontactinterface ktnef)
 makedepends=(extra-cmake-modules kdoctools kdesignerplugin boost python3)
 optdepends=('kleopatra: mail encryption support' 'kdepim-addons: additional plugins')
 conflicts=(ktnef)

kmailtransport/PKGBUILD

@@ -7,7 +7,7 @@ pkgdesc="Mail Transport Service"
 arch=('x86_64')
 url="https://projects.kde.org/$pkgname"
 license=(LGPL)
-depends=(akonadi-mime kcmutils ksmtp)
+depends=(akonadi-mime kcmutils ksmtp libkgapi)
 makedepends=(extra-cmake-modules python kdoctools boost)
 options=('debug')
 source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})

kpat/PKGBUILD

@@ -8,8 +8,8 @@ pkgdesc="Collection of various patience games"
 arch=('x86_64')
 url='http://www.kde.org'
 license=('GPL' 'LGPL' 'FDL')
-depends=('knotifyconfig' 'libkdegames' 'kdelibs4support')
-makedepends=('extra-cmake-modules' 'kdoctools' 'python3')
+depends=(libkdegames freecell-solver hicolor-icon-theme)
+makedepends=(extra-cmake-modules kdoctools)
 groups=('kde' 'kde-uninstall' 'kde-applications' 'kdegames')
 replaces=('kdegames-kpat')
 conflicts=('kdegames-kpat')

ktnef/PKGBUILD

@@ -0,0 +1,36 @@
+pkgname=ktnef
+pkgver=18.07.80
+pkgrel=1
+pkgdesc="API for handling TNEF data"
+arch=(x86_64)
+url="https://community.kde.org/KDE_PIM"
+license=(LGPL)
+depends=(kcalutils kcontacts)
+makedepends=(extra-cmake-modules)
+conflicts=(libktnef)
+provides=(libktnef)
+replaces=(libktnef)
+source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('4fa715d50c9f4aa07d0f4a1351d00369816ca2565f6b866dc663cf6172a23c6b'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}
+

libktnef/PKGBUILD

@@ -1,41 +0,0 @@
-# Include global configuration
-
-_pkgname=ktnef
-pkgname=lib$_pkgname
-pkgver=18.07.80
-pkgrel=1
-pkgdesc="API for handling TNEF data"
-arch=(x86_64)
-url="https://projects.kde.org/$pkgname"
-license=(LGPL)
-depends=(kcalutils kcontacts)
-makedepends=(extra-cmake-modules python kdoctools)
-options=('docs' 'debug')
-source=("https://download.kde.org/unstable/applications/$pkgver/src/$_pkgname-$pkgver.tar.xz"{,.sig})
-sha256sums=('4fa715d50c9f4aa07d0f4a1351d00369816ca2565f6b866dc663cf6172a23c6b'
-            'SKIP')
-validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
-              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>
-
-prepare() {
-  mkdir -p build
-}
-
-build() {
-  cd build
-  cmake ../${_pkgname}-${pkgver} \
-         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
-        -DCMAKE_INSTALL_PREFIX=/usr \
-        -DKDE_INSTALL_LIBDIR=lib \
-        -DKDE_INSTALL_SYSCONFDIR=/etc \
-        -DKDE_INSTALL_LIBEXECDIR=lib \
-        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
-        -DBUILD_TESTING=OFF \
-        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
-  make
-}
-
-package() {
-  cd build
-  make DESTDIR=${pkgdir} install
-}

perl-appconfig/PKGBUILD

@@ -0,0 +1,29 @@
+pkgname=perl-appconfig
+_realname=AppConfig
+pkgver=1.71
+pkgrel=1
+pkgdesc="Perl/CPAN AppConfig module - Read configuration files and parse command line arguments"
+arch=('any')
+license=('PerlArtistic' 'GPL')
+url="http://search.cpan.org/dist/${_realname}/"
+depends=('perl')
+options=('!emptydirs')
+source=("http://www.cpan.org/authors/id/N/NE/NEILB/${_realname}-${pkgver}.tar.gz")
+md5sums=('7747d9241561ed5567d5e134b8648707')
+
+build() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+  perl Makefile.PL INSTALLDIRS=vendor
+  make
+}
+
+check() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+  make test
+}
+
+package() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+  make install DESTDIR="${pkgdir}"
+}
+

perl-path-tiny/PKGBUILD

@@ -0,0 +1,40 @@
+
+pkgname=perl-path-tiny
+pkgver=0.104
+pkgrel=1
+pkgdesc='File path utility'
+arch=(any)
+license=(PerlArtistic GPL)
+options=(!emptydirs)
+depends=('perl')
+url=https://metacpan.org/release/Path-Tiny
+source=("http://search.cpan.org/CPAN/authors/id/D/DA/DAGOLDEN/Path-Tiny-$pkgver.tar.gz")
+md5sums=(17354181d9794df01be555b25114dd24)
+sha512sums=(6574e48645ebb4f61d45c1365e8b63cfaac6423394ba08363cfd62d3d98d163bd333d997bf5f7fd0e37ff94fcb3a3e19871eb7499b295399f048fd6a4bd3c78c)
+_ddir="Path-Tiny-$pkgver"
+
+build()
+(
+  cd "$srcdir/$_ddir"
+  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
+  unset PERL5LIB PERL_MM_OPT
+  /usr/bin/perl Makefile.PL
+  make
+)
+
+check()
+(
+  cd "$srcdir/$_ddir"
+  export PERL_MM_USE_DEFAULT=1
+  unset PERL5LIB
+  make test
+)
+
+package()
+(
+  cd "$srcdir/$_ddir"
+  make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
+  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
+)
+
+

perl-template-toolkit/PKGBUILD

@@ -0,0 +1,36 @@
+
+pkgname=perl-template-toolkit
+pkgver=2.27
+pkgrel=1
+pkgdesc="Perl template processing system"
+arch=('x86_64')
+url="http://search.cpan.org/dist/Template-Toolkit/"
+license=('PerlArtistic')
+depends=('perl-appconfig' 'perl')
+options=('!emptydirs')
+source=(http://search.cpan.org/CPAN/authors/id/A/AB/ABW/Template-Toolkit-$pkgver.tar.gz)
+md5sums=('a7fae5d4fe5918f33105d92a62134067')
+
+build() {
+  cd Template-Toolkit-$pkgver
+  perl Makefile.PL INSTALLDIRS=vendor TT_ACCEPT=y
+  make
+}
+
+check() {
+  cd Template-Toolkit-$pkgver
+  make test
+}
+
+package() {
+  cd Template-Toolkit-$pkgver
+  make install DESTDIR="${pkgdir}"
+# template start; name=perl-binary-module-dependency; version=1;
+if [[ $(find "$pkgdir/usr/lib/perl5/" -name "*.so") ]]; then
+	_perlver_min=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]);')
+	_perlver_max=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]+1);')
+	depends+=("perl>=$_perlver_min" "perl<$_perlver_max")
+fi
+# template end;
+}
+

python3-random2/PKGBUILD

@@ -0,0 +1,18 @@
+_pipname=random2
+pkgname=python3-$_pipname
+pkgver=1.0.1
+pkgrel=1
+pkgdesc="Python 3 compatible port of Python 2 random module"
+arch=(any)
+url="https://pypi.org/project/random2/"
+license=(PSF)
+depends=(python3)
+makedepends=(python3-setuptools)
+source=("https://pypi.python.org/packages/source/${_pipname:0:1}/$_pipname/$_pipname-$pkgver.zip")
+sha256sums=('34ad30aac341039872401595df9ab2c9dc36d0b7c077db1cea9ade430ed1c007')
+
+package() {
+  cd $_pipname-$pkgver
+  python3 setup.py install --root="$pkgdir" --optimize=1
+}
+

zxing-cpp/PKGBUILD

@@ -0,0 +1,31 @@
+pkgname=zxing-cpp
+pkgver=git20180320
+pkgrel=1
+_commit=5aad4744a3763d814df98a18886979893e638274
+pkgdesc="A command-line tool to decode QRCode"
+arch=(x86_64)
+url="https://github.com/glassechidna/zxing-cpp"
+license=(Apache)
+depends=(gcc-libs)
+makedepends=(git cmake opencv)
+optdepends=('opencv: support for opencv')
+source=("$pkgname::git+https://github.com/glassechidna/zxing-cpp.git#commit=$_commit")
+sha512sums=('SKIP')
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_CXX_FLAGS="${CXXFLAGS} -fPIC"
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}
+