# $Id: PKGBUILD 168343 2012-10-09 04:08:52Z tdziedzic $
# Maintainer: Thomas Dziedzic <gostrc@gmail.com>
# Maintainer: Vesa Kaihlavirta <vesa@archlinux.org>
# Special note for devs looking to upgrade this package:
#   ghc places a unique hash for each library when it is built.
#   Libraries depend on versions specified by those hashes.
#   This implies that all libraries need to be rebuilt when ghc is rebuilt.

pkgname=ghc
pkgver=7.10.3
pkgrel=1
pkgdesc='The Glasgow Haskell Compiler'
arch=('i686' 'x86_64')
url='http://www.haskell.org/ghc/'
license=('custom')
depends=('perl' 'gmp>=5.0' 'gcc' 'libffi')
makedepends=('ghc' 'perl' 'libxslt' 'docbook-xsl')
checkdepends=('python2')
install='ghc.install'
options=('staticlibs')
# missing rtl?
# missing integer-gmp2
provides=('haskell-array=0.5.1.0'
          'haskell-base=4.8.0.0'
          'haskell-bin-package-db=0.0.0.0'
          'haskell-binary=0.7.3.0'
          'haskell-bytestring=0.10.6.0'
          'haskell-containers=0.5.6.2'
          'haskell-deepseq=1.4.1.1'
          'haskell-directory=1.2.2.0'
          'haskell-filepath=1.4.0.0'
          'haskell-ghc-prim=0.4.0.0'
          'haskell-haskeline=0.7.2.1'
          'haskell-hoopl=3.10.0.2'
          'haskell-hpc=0.6.0.2'
          'haskell-integer-gmp=0.5.1.0'
          'haskell-pretty=1.1.2.0'
          'haskell-process=1.2.3.0'
          'haskell-template-haskell=2.10.0.0'
          'haskell-terminfo=0.4.0.1'
          'haskell-time=1.5.0.1'
          'haskell-transformers=0.4.2.0'
          'haskell-unix=2.7.1.0'
          'haskell-xhtml=3000.2.1'
          'haskell-cabal=1.22.2.0'
         )
replaces=('haskell-array<0.5.1.0'
          'haskell-base<4.8.0.0'
          'haskell-bin-package-db<0.0.0.0'
          'haskell-binary<0.7.3.0'
          'haskell-bytestring<0.10.6.0'
          'haskell-containers<0.5.6.2'
          'haskell-deepseq<1.4.1.1'
          'haskell-directory<1.2.2.0'
          'haskell-filepath<1.4.0.0'
          'haskell-ghc-prim<0.4.0.0'
          'haskell-haskeline<0.7.2.1'
          'haskell-hoopl<3.10.0.2'
          'haskell-hpc<0.6.0.2'
          'haskell-integer-gmp<0.5.1.0'
          'haskell-pretty<1.1.2.0'
          'haskell-process<1.2.3.0'
          'haskell-template-haskell<2.10.0.0'
          'haskell-terminfo<0.4.0.1'
          'haskell-time<1.5.0.1'
          'haskell-transformers<0.4.2.0'
          'haskell-unix<2.7.1.0'
          'haskell-xhtml<3000.2.1'
          'haskell-cabal<1.22.2.0'
         )

source=("http://www.haskell.org/ghc/dist/${pkgver}/ghc-${pkgver}-src.tar.bz2"
        "http://www.haskell.org/ghc/dist/${pkgver}/ghc-${pkgver}-testsuite.tar.bz2"
        'build.mk')
md5sums=('afd94782875acc57673965fe890246b0'
         'bc158a295231b8846463ed847ab2a5b6'
         'c367ef26300648ee9b8aca3dee5c9669')

build() {
  cd ghc-${pkgver}

  cp ${srcdir}/build.mk mk/build.mk

  ./configure \
    --prefix=/usr \
    --with-system-libffi \
    --with-ffi-includes=/usr/lib/libffi-3.2.1/include

  make
}

check() {
  # keep this otherwise a lot of tests will show as unexpected failures... need to investigate why using -jn for n > 1 does this...
  unset MAKEFLAGS

  cd ghc-${pkgver}

  # python2 rename
  #sed -e 's/PYTHON = python/&2/' -i testsuite/mk/boilerplate.mk
  sed -e 's_#!/usr/bin/env python$_&2_' -i testsuite/timeout/calibrate testsuite/timeout/timeout.py

  # upstream known failures on both i686 and x86_64:
  #    ghci.debugger/scripts     break011 [bad stderr] (ghci)
  #    perf/compiler             parsing001 [stat not good enough] (normal)
  #    simplCore/should_compile  spec-inline [stderr mismatch] (optasm)
  # upstream known failures on i686 only:
  #    numrun012 test fails on i686 works on x86_64 - http://hackage.haskell.org/trac/ghc/ticket/5856
  make test

  # enabling threads to speed up
  # causes more failures than make test, need to investigate
  # upstream known failures on both i686 and x86_64:
  #    perf/compiler             parsing001 [stat not good enough] (normal)
  #    simplCore/should_compile  spec-inline [stderr mismatch] (optasm)
  # upstream known failures on i686 only:
  #    numrun012 test fails on i686 works on x86_64 - http://hackage.haskell.org/trac/ghc/ticket/5856
  #make THREADS=9 test

  # will most likely cause lots of failures
  # enable this when upstream has 0 test failures from a simple 'make test'
  # zero unexpected failures on all tier 1 platforms - http://hackage.haskell.org/trac/ghc/ticket/5757
  #make fulltest
}

package() {
  cd ghc-${pkgver}

  make DESTDIR=${pkgdir} install

  install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/ghc/LICENSE
}