pkgname=skrooge
pkgver=2.0.0
pkgrel=1
pkgdesc="Allows you to manage your personal finances in KDE"
arch=('x86_64')
url="http://skrooge.org"
license=('GPL')
depends=('grantlee-qt5' 'karchive' 'kconfig' 'kcoreaddons' 'ki18n' 'kitemviews'
         'kwidgetsaddons' 'kwindowsystem' 'kcompletion' 'kdoctools' 'kjobwidgets'
         'kconfigwidgets' 'kdesignerplugin' 'kiconthemes' 'kio' 'knewstuff' 'kparts'
         'kwallet' 'kxmlgui' 'knotifyconfig' 'kdelibs4support' 'krunner' 'libofx' 
         'qt5-tools' 'python3' 'qca-qt5')
makedepends=('cmake' 'xdg-utils' 'extra-cmake-modules')
categories=('office')
install=$pkgname.install
source=("http://download.kde.org/stable/skrooge/$pkgname-$pkgver.tar.xz")
sha256sums=('50da4dde01b85b2b0ba16902a05664910d4f2dbaa828370ee44c9f89e2efd6b5')

build() {
  cd $srcdir/$pkgname-$pkgver

  [[ -d build ]] && rm -r build
  mkdir build && cd build
  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    ..
  make
}
 
package() {
  cd $srcdir/$pkgname-$pkgver/build
  make DESTDIR=$pkgdir install
}