#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

pkgname=qtcreator
pkgver=2.1.0
pkgrel=1
_qtver=4.7.1
pkgdesc="Lightweight, cross-platform integrated development environment"
arch=('i686' 'x86_64')
url="http://trolltech.com/developer/qt-creator"
license=('LGPL')
makedepends=()
depends=('qt>=4.7.')
optdepends=('qt-doc: for the integrated Qt documentation'
            'gdb: for the debugger')
options=(docs)
source=("http://get.qt.nokia.com/qtcreator/qt-creator-${pkgver}-src.zip"
	"ftp://ftp.qt.nokia.com/qt/source/qt-everywhere-opensource-src-${_qtver}.tar.gz"
        qtcreator.desktop)

md5sums=('a6e48b4347314fb2a92b77f40b4fc9a5'
	 '6f88d96507c84e9fea5bf3a71ebeb6d7'
         '2c3ffbd66845b37be9804f2966815a10')
         

build() {

  export QTDIR="${srcdir}/qt-everywhere-opensource-src-${_qtver}"
  export QTCREATOR_WITH_QML=1

  if [ -d ${srcdir}/build ]; then
    rm -rf ${srcdir}/build
  fi

  mkdir ${srcdir}/build
  cd ${srcdir}/build

  qmake ${srcdir}/qt-creator-${pkgver}-src/qtcreator.pro
  make
}

package() {
  cd ${srcdir}/build

  make INSTALL_ROOT="${pkgdir}/usr/" install

  install -Dm644 ${srcdir}/qtcreator.desktop \
    ${pkgdir}/usr/share/applications/qtcreator.desktop
  install -Dm644 ${srcdir}/qt-creator-${pkgver}-src/LGPL_EXCEPTION.TXT \
    ${pkgdir}/usr/share/licenses/qtcreator/LGPL_EXCEPTION.TXT
}