pkgname=okteta
pkgver=0.25.1
pkgrel=1
epoch=1
arch=('x86_64')
pkgdesc="KDE hex editor for viewing and editing the raw data of files"
url="https://kde.org/applications/utilities/okteta/"
screenshot="https://www.kde.org/images/screenshots/okteta.png"
groups=("kde" "kde-devel" "kdesdk" "kde-uninstall")
depends=('kcmutils' 'kparts' 'knewstuff' 'qca-qt5')
makedepends=('extra-cmake-modules' 'kdoctools' 'python3' 'qt5-tools' 'hicolor-icon-theme')
replaces=('kdesdk-okteta')
conflicts=('kdesdk-okteta')
provides=('kdesdk-okteta')
license=('GPL' 'LGPL' 'FDL')
source=("https://download.kde.org/stable/$pkgname/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('20f69089f6c1b0fe72a600caa4b255a7cebd7d4fae191a0d3cade57b28f7149a'
            'SKIP')
validpgpkeys=(E191FD5BE6F46870F09E82B2024E7FB43D015474)  # Friedrich W. H. Kossebau <kossebau@kde.org>

prepare() {
  mkdir build
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DBUILD_TESTING=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}