#
# <Repo> Packages for Chakra, part of chakra-project.org
#
# Maintainer: <Maintainer contact information>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=mumble
pkgver=1.2.3
pkgrel=3
arch=('i686' 'x86_64')
pkgdesc="A voice chat application similar to TeamSpeak."
license=('BSD')
depends=('qt' 'speex' 'lsb-release' 'libxi' 'avahi' 'libsndfile' 'protobuf' 'libpulse')
makedepends=('boost' 'mesa' 'avahi')
url="http://mumble.sourceforge.net/"
source=("http://downloads.sourceforge.net/mumble/$pkgname-$pkgver.tar.gz")
md5sums=('55804e3dfe98b16eeb40abca6c254625')

build() {
  cd $srcdir/$pkgname-$pkgver

  # Building mumble
  /usr/bin/qmake main.pro \
    CONFIG+="bundled-celt no-bundled-speex no-speechd no-g15 no-xevie no-server no-embed-qt-translations packaged" \
    DEFINES+="PLUGIN_PATH=/usr/lib/mumble"
  make release
}

package() {
  cd $srcdir/$pkgname-$pkgver

  # bin stuff
  install -m755 -D ./release/mumble $pkgdir/usr/bin/mumble
  install -m755 -D ./scripts/mumble-overlay $pkgdir/usr/bin/mumble-overlay

  # lib stuff
  install -m755 -D ./release/libmumble.so.$pkgver $pkgdir/usr/lib/mumble/libmumble.so.$pkgver
  ln -s libmumble.so.$pkgver $pkgdir/usr/lib/mumble/libmumble.so
  ln -s libmumble.so.$pkgver $pkgdir/usr/lib/mumble/libmumble.so.1
  ln -s libmumble.so.$pkgver $pkgdir/usr/lib/mumble/libmumble.so.1.2

  install -m755 -D ./release/plugins/liblink.so $pkgdir/usr/lib/mumble/liblink.so
  install -m755 -D ./release/plugins/libmanual.so $pkgdir/usr/lib/mumble/libmanual.so
  install -m755 -D ./release/libcelt* $pkgdir/usr/lib/mumble/

  # other stuff
  install -m644 -D ./scripts/mumble.desktop $pkgdir/usr/share/applications/mumble.desktop
  install -m755 -d $pkgdir/usr/share/man/man1
  install -m644 -D ./man/mum* $pkgdir/usr/share/man/man1/
  install -m644 -D ./icons/mumble.svg $pkgdir/usr/share/icons/hicolor/scalable/apps/mumble.svg

  # License.
  install -m644 -D $srcdir/$pkgname-$pkgver/LICENSE \
		   $pkgdir/usr/share/licenses/$pkgname/LICENSE
  
}