# Include global configuration
source ../kdeapps.conf

pkgname=akonadi
pkgver=${_kdever}
pkgrel=1
pkgdesc="PIM layer, which provides an asynchronous API to access all kind of PIM data"
arch=('x86_64')
url='http://community.kde.org/KDE_PIM/Akonadi'
license=('LGPL')
depends=('shared-mime-info' 'qt5-base' 'libxslt' 'mariadb' 'kitemviews' 'kio'
        'kdesignerplugin' 'kitemmodels' 'boost')
makedepends=('extra-cmake-modules' 'postgresql')
checkdepends=('xorg-server-xvfb')
optdepends=('postgresql: PostgreSQL backend'
            'mariadb: MariaDB backend')
install="${pkgname}.install"
conflicts=('akonadi-client')
provides=('akonadi-client' 'akonadi-qt4')
replaces=('akonadi-client' 'akonadi-qt4')
source=("$_mirror/${pkgname}-$_kdever.tar.xz")
sha256sums=(`grep ${pkgname}-$_kdever.tar.xz  ../checksums.txt | cut -d " " -f1`)

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake_kf5 ../${pkgname}-${pkgver}
  make
}

check() {
  # 17 akonadi-dbconfigtest failed as we changed the default backend
  # 24~30 failed due to qt cannot find the sqldriver which is not installed yet
  cd build
  xvfb-run -a dbus-launch --exit-with-session make test || warning "Tests failed"
}

package() {
  cd build
  make DESTDIR=${pkgdir} install
}