# Apps Packages for Chakra, part of www.chakra-project.org
# Maintainer: H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Stephen McIntosh <stephenmac7[at]gmail[dot]com>
#               Thomas Dziedzic <gostrc@gmail.com>
#               Vesa Kaihlavirta <vesa@archlinux.org>
#               Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=xmonad
pkgname=xmonad
pkgver=0.11
pkgrel=1
pkgdesc="A lightweight X11 tiled window manager written in Haskell"
url="http://hackage.haskell.org/package/xmonad"
license=('custom:BSD3')
arch=('x86_64' 'i686')
makedepends=()
depends=('ghc=7.6.3-1' 'haskell-X11>=1.5' 'haskell-X11<1.7' 'haskell-base>=3' 'haskell-base<5' 'haskell-containers' 'haskell-directory' 'haskell-extensible-exceptions' 'haskell-filepath' 'haskell-mtl' 'haskell-process' 'haskell-unix' 'haskell-utf8-string>=0.3.0' 'gmp' 'sh')
options=()
source=("http://hackage.haskell.org/packages/archive/xmonad/0.11/xmonad-0.11.tar.gz")
install="xmonad.install"
sha512sums=('34740f032508584f34f6b138d21394eca17e8020bccc4d8c6e8b3cb6b7ca64b153077cfd16636a6130768ebd145fe993569f8a229862d7816d0c89c905ee08bc')

build() {
    cd "${srcdir}/xmonad-0.11"
    runhaskell Setup configure \
        -O \
        ${PKGBUILD_HASKELL_ENABLE_PROFILING:+-p } \
        --enable-split-objs \
        --enable-shared \
        --prefix="/usr" \
        --docdir="/usr/share/doc/xmonad" \
        --libsubdir='$compiler/site-local/$pkgid'
    runhaskell Setup build
    runhaskell Setup haddock
    runhaskell Setup register   --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
    cd "${srcdir}/xmonad-0.11"
    install -D -m744 register.sh \
        "${pkgdir}/usr/share/haskell/xmonad/register.sh"
    install -m744 unregister.sh \
        "${pkgdir}/usr/share/haskell/xmonad/unregister.sh"
    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"

    # Documentation
    ln -s "/usr/share/doc/xmonad/html" \
        "${pkgdir}/usr/share/doc/ghc/html/libraries/xmonad"

    # License
    install -D -m644 LICENSE \
        "${pkgdir}/usr/share/licenses/xmonad/LICENSE"
    rm -f "${pkgdir}/usr/share/doc/xmonad/LICENSE"

    runhaskell Setup copy --destdir="${pkgdir}"
}