#
# Chakra Packages for Chakra, part of chakra-project.org
#
# contributor (x86_64): Giuseppe Calà <jiveaxe@gmail.com>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=tor
pkgver=0.2.1.29
pkgrel=1
pkgdesc="Anonymizing overlay network"
arch=('i686' 'x86_64')
url="http://www.torproject.org/"
license=('BSD')
depends=('openssl' 'libevent' 'tsocks' 'bash')
backup=('etc/tor/torrc' 'etc/tor/torrc-dist' 'etc/tor/tor-tsocks.conf')
install=tor.install
source=(http://www.torproject.org/dist/${pkgname}-${pkgver}.tar.gz
	'tor.conf'
	'tor.rc')
md5sums=('1cd4feea84f2b066717b500d090bcf65'
         'c97998c760c4351f12ad41d514071a9b'
         '23348b8e3b38c6ed2a45b4be42a7de8e')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var || return 1
  make || return 1
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make DESTDIR="$pkgdir" install || return 1

  install -d ${pkgdir}/var/lib/tor || return 1
  
  mv "$pkgdir/etc/tor/torrc.sample" "$pkgdir/etc/tor/torrc-dist" || return 1
  install -D -m644 "$srcdir/tor.conf" "$pkgdir/etc/tor/torrc" || return 1
  install -D -m755 "$srcdir/tor.rc" "$pkgdir/etc/rc.d/tor" || return 1
  
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${pkgname}/LICENSE" || return 1
}