pkgname=amarok
pkgver=2.9.70
pkgrel=1
pkgdesc="A media player for KDE"
arch=('x86_64')
url="https://amarok.kde.org"
screenshot="http://amarok.kde.org/files/Amarok-2.6-InDulciJubilo-screenie4.png"
license=('GPL2' 'LGPL2.1' 'FDL')
depends=('qt5-base' 'qt5-quickcontrols2' 'qt5-webengine' 'qt5-declarative' 'qt5-script' 'qt5-svg' 'mariadb' 'taglib-extras' 'ffmpeg' 
         'libofa' 'libbluray' 'libmygpo-qt5' 'karchive' 'attica-qt5' 'kcodecs' 'kcoreaddons' 'kcrash' 'kdbusaddons' 'kdeclarative' 'kdnssd'
         'kglobalaccel' 'kguiaddons' 'ki18n' 'kiconthemes' 'kcmutils' 'kio' 'knewstuff' 'knotifications' 'knotifyconfig' 'kpackage' 'solid' 'ktexteditor'
         'threadweaver' 'kwidgetsaddons' 'kwindowsystem' 'kirigami' 'phonon-qt5' 'phonon-qt5-backend-vlc' 'phonon-qt5-backend-gstreamer')
makedepends=('pkgconfig' 'extra-cmake-modules' 'cmake' 'libgpod' 'libmtp' 'docbook-xsl' 'mesa' 'clamz' 'loudmouth' 'liblastfm' 'audiocd-kio')
optdepends=("libgpod: support Apple iPod audio devices"
            "libmtp: support for portable media devices"
            "ifuse: support for Apple iPod Touch and iPhone"
            "clamz: allow to download songs from Amazon.com"
            "loudmouth: backend needed by mp3tunes for syncing")
categories=('multimedia')
source=("$pkgname-$pkgver::git+https://github.com/KDE/amarok.git#commit=5d463f47d149391a2303215222105d89528a571a")
sha256sums=('SKIP')

build() {
  cd $pkgname-$pkgver

  mkdir build
  cd build
  cmake .. \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -D_BUILD_TESTING=OFF \
    -DWITH_QTWEBKIT=OFF
  make
}

package(){
  cd $pkgname-$pkgver/build
  make DESTDIR=$pkgdir install
}