# Apps Packages for Chakra, part of www.chakra-project.org
# Maintainer: H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Inkane <neoinkaneglade@aol.com>
#               Sergej Pupykin <pupykin.s+arch@gmail.com>
#               Vesa Kaihlavirta <vegai@iki.fi>
#               shild <shildv@gmail.com>

pkgname=xmonad
pkgver=0.10
pkgrel=4
pkgdesc='A lightweight X11 tiled window manager written in Haskell'
arch=('i686' 'x86_64')
url='http://xmonad.org/'
license=('BSD')
depends=('ghc'
         'gmp'
         'haskell-x11'
         'haskell-mtl'
         'haskell-utf8-string'
         'sh')
optdepends=('xorg-xmessage: for displaying visual error messages')
install='xmonad.install'
source=(http://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz
        xmonad.desktop
        xmonad.session
        xmonad.svg)
md5sums=('f8381e1ec15137863558a454d4466467'
         'f8e3d84a9f154d1b5d7fcffbc0a058c9'
         '9d1bc84a7f32897d32f3fc71ef76228e'
         '72bfa5e62e4e44fe7fa59b6a7593d993')

build() {
    cd $srcdir/$pkgname-$pkgver
    runhaskell Setup.lhs configure \
        --ghc \
        --enable-shared \
        --enable-split-objs \
        --prefix=/usr \
        --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
    cd $srcdir/$pkgname-$pkgver
    install -D -m744 register.sh \
        $pkgdir/usr/share/haskell/$pkgname/register.sh
    install -m744 unregister.sh \
        $pkgdir/usr/share/haskell/$pkgname/unregister.sh
    runhaskell Setup.lhs copy --destdir=$pkgdir
    #runhaskell util/GenerateManpage.hs
    install -D -m644 man/xmonad.1 \
        $pkgdir/usr/share/man/man1/xmonad.1
    install -D -m644 LICENSE \
        $pkgdir/usr/share/licenses/xmonad/LICENSE
    install -D -m644 $srcdir/xmonad.desktop \
        $pkgdir/usr/share/xsessions/xmonad.desktop
    install -D -m644 $srcdir/xmonad.session \
        $pkgdir/usr/share/gnome-session/sessions/xmonad.session
    install -D -m644 $srcdir/xmonad.svg \
        $pkgdir/usr/share/pixmaps/xmonad.svg
}