#
# Games Packages for Chakra, part of chakra-project.org
#
# Maintainer: Adrián Chaves Fernández (Gallaecio)

pkgname=hedgewars
pkgver=0.9.16
pkgrel=1
pkgdesc="Free turn based strategy game similar to Worms™"
arch=('i686' 'x86_64')
url="http://hedgewars.org"
license=('GPL2')
depends=('lua' 'qt' 'sdl' 'sdl_mixer' 'sdl_image' 'sdl_net' 'sdl_ttf' 'ttf-dejavu')
makedepends=('fpc' 'cmake' 'ghc' 'haskell-utf8-string' 'haskell-dataenc'
'haskell-network' 'haskell-hslogger')
source=(http://download.gna.org/$pkgname/$pkgname-src-$pkgver.tar.bz2)
md5sums=('04f28f454e370a101cbf0d82c6d39bce')

build() {
  cd $srcdir/$pkgname-src-$pkgver
  mkdir build && cd build
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        ..
  make
}
 
package() {
  cd $srcdir/$pkgname-src-$pkgver/build
  make DESTDIR=$pkgdir install

  # DejaVu Font.
  rm $pkgdir/usr/share/$pkgname/Data/Fonts/DejaVuSans-Bold.ttf
  ln -s /usr/share/fonts/TTF/DejaVuSans-Bold.ttf $pkgdir/usr/share/$pkgname/Data/Fonts/DejaVuSans-Bold.ttf
  
}