# Apps packages for Chakra

pkgname=pology
pkgver=0.12
pkgrel=1
pkgdesc='A framework for custom processing of PO files.'
arch=('x86_64')
license=('GPL3')
url='http://techbase.kde.org/Localization/Tools/Pology'
depends=('python2' 'gettext')
makedepends=('cmake' 'docbook-xsl' 'docbook-xml' 'epydoc')
optdepends=('python2-pyenchant: to spell check'
	    'aspell-lang: a dictionary in your language'
	    'hunspell-lang: a dictionary in your language'
	    'languagetool: used by the check-grammar sieve'
	    'dbus-python: for communication with Lokalize'
	    'apertium: used by the pomtrans script'
	    'git: for processing files under version control'
	    'subversion: for processing files under version control')
conflicts=('pology-svn')
source=(http://pology.nedohodnik.net/release/$pkgname-$pkgver.tar.bz2)
md5sums=('4eb9f48e3b852ba65ffcc071f93b4caa')
options=(!makeflags)

build() {
  cd $srcdir/$pkgname-$pkgver

  sed -i -e 's|^#!/usr/bin/env python$|#!/usr/bin/env python2|' $(find $srcdir -name '*.py')

  mkdir -p build && cd build
  cmake .. -DCMAKE_INSTALL_PREFIX=/usr -DDOCBOOK_XSL_DIR=/usr/share/xml/docbook/xsl-stylesheets-1.77.1/
  make PREFIX=/usr
}

package() {
  cd $srcdir/$pkgname-$pkgver/build
  make PREFIX=/usr DESTDIR="$pkgdir" install

  install -d $pkgdir/usr/share/apps/katepart/syntax
  ln -s /usr/share/pology/syntax/kate/synder.xml $pkgdir/usr/share/apps/katepart/syntax/synder.xml

  install -d $pkgdir/etc/bash_completion.d
  ln -s /usr/share/pology/completion/bash/pology $pkgdir/etc/bash_completion.d/pology
}