# Transitional package for KDE-Unstable

pkgname=soprano-git
pkgver=20120526
pkgrel=1
pkgdesc="A library which provides a highly usable object-oriented C++/Qt4 framework for RDF data"
arch=('i686' 'x86_64')
url="http://soprano.sourceforge.net/"
license=('GPL')
depends=('qt' 'redland-storage-virtuoso' 'libiodbc' 'virtuoso')
makedepends=('cmake' 'doxygen' 'git')
conflicts=('soprano')
provides=('soprano')

_gitroot="git://anongit.kde.org/soprano"
_gitname="soprano"


build() {
  cd $srcdir
  msg "Connecting to the GIT server...."
  
  if [[ -d $srcdir/$_gitname ]] ; then
    cd $_gitname
    git pull origin
    msg "The local files are updated."
  else
    git clone $_gitroot
  fi
  
  msg "GIT checkout done"
  msg "Starting make..."
  if [[ -d ${srcdir}/build ]]; then
    msg "Cleaning the previous build directory..."
    rm -rf ${srcdir}/build
  fi
  mkdir $srcdir/build
  cd $srcdir/build
  cmake ${srcdir}/$_gitname -DCMAKE_BUILD_TYPE=release \
		-DCMAKE_SKIP_RPATH=OFF \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DSOPRANO_DISABLE_CLUCENE_INDEX=ON
  make
}

package() {
  cd ${srcdir}/build
  make DESTDIR=${pkgdir} install
}