#
# Apps Packages for Chakra, part of chakra-project.org
# Maintainer: Neophytos Kolokotronis <tetris4@gmail.com>
# Contributor: arriagga <ramon.arriaga@gmail.com>
# Contributor: dieghen89 <dieghen89@gmail.com>

pkgname=musique
pkgver=1.3
pkgrel=1
pkgdesc="Just another music player, only better"
arch=('i686' 'x86_64')
url="http://flavio.tordini.org/musique"
license=('GPL3')
depends=('qt>=4.5' 'desktop-file-utils' 'hicolor-icon-theme' 'phonon' 'taglib' 'sqlite3')
optdepends=('gstreamer0.10-plugins: for gstreamer backend'
            'phonon-gstreamer: gstreamer backend'
            'phonon-mplayer-git: mplayer backend'
            'phonon-vlc: vlc backend'
            'phonon-xine: xine backend')
conflicts=('$pkgname-git')
replaces=('minitunes' 'minitunes-git')
categories=('multimedia')
source=("http://flavio.tordini.org/files/musique/${pkgname}-${pkgver}.tar.gz")
sha256sums=('401643ad9c750270a89d431806044c626dee3fe7ebc14d0ac72917197cdd0592')

prepare() {
  cd ${pkgname}
  # Disable GTK integration (will not build in Chakra otherwise).
  sed -e "/Fall back to gconf/,+3d" -i src/main.cpp
}

build() {
  cd ${pkgname}
  qmake PREFIX=/usr
}

package() {
  cd ${pkgname}
  make INSTALL_ROOT="${pkgdir}" install
  install -Dm644 "${srcdir}/${pkgname}/data/128x128/${pkgname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
}