# Maintainer:   H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Manuel Tortosa <manutortosa@chakra-project.org>

# Include global configuration
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=kdebindings-smokekde
_pkgname=smokekde
pkgver=${_kdever}
pkgrel=1
pkgdesc="Language independent library for KDE bindings"
url="http://kde.org/"
arch=('x86_64')
license=('GPL' 'LGPL' 'FDL')
depends=("kdebindings-smokeqt>=${_kdever}"
         "kdepimlibs>=${_kdever}"
         "soprano>=2.8.0")
makedepends=('cmake'
             'automoc4'
             "kdebindings-smokegen>=${_kdever}"
             "kdegraphics-okular>=${_kdever}"
             "kdesdk-kate>=${_kdever}")
replaces=('kdebindings-common')
groups=("kde" "kdebindings" "kde-uninstall")
provides=('smokekde')
options=('docs' '!header' 'debug' 'log')
source=("$_mirror/${_pkgname}-$_kdever.tar.xz")
sha256sums=(`grep ${_pkgname}-$_kdever.tar.xz  ../checksums.txt | cut -d " " -f1`)

build() {
    cd "${srcdir}"
    rm -rf build
    mkdir build
    cd build
    cmake ../smokekde-${pkgver} \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr 
    make
}

package() {
    cd "${srcdir}"/build
    make DESTDIR="${pkgdir}" install
}