pkgname=clementine-qt5
_pkgname=Clementine
pkgver=1.2.3.r1378.ge0578a2
pkgrel=1
pkgdesc="Experimental Qt5 version of Clementine, a modern music player and library organiser."
arch=('x86_64')
license=('GPL')
depends=('gstreamer' 'taglib' 'glew' 'desktop-file-utils' 'hicolor-icon-theme'
         'qt5-base' 'libechonest' 'protobuf' 'crypto++' 'chromaprint'
         'libmygpo-qt5' 'qt5-x11extras' 'libgpod' 'liblastfm' 'sparsehash' 'libcdio' 'libmtp' 'fftw')
makedepends=('git' 'boost' 'cmake' 'mesa' 'qt5-tools')
install=clementine.install
optdepends=('gst-pluginsbase: for more open formats'
            'gst-pluginsgood: for use with "Good" plugin libraries'
            'gst-pluginsbad: for use with "Bad" plugin libraries'
            'gst-pluginsugly: for use with "Ugly" plugin libraries'
            'libspotify: add support for Spotify, due to license restriction, please build it 
                         with ccr yourself'
            'dropbox: add support for Dropbox')
url="http://www.clementine-player.org/"
source=('git+https://github.com/clementine-player/Clementine.git#commit=e0578a2')
sha256sums=('SKIP')
conflicts=('clementine' 'clementine-lxqt' 'clementine-git' 'clementine-qt5-git')


pkgver() {
  cd ${srcdir}/${_pkgname}
  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd ${srcdir}/${_pkgname}
  mkdir -p build
}
build() {
  cd ${srcdir}/${_pkgname}/build
  cmake ".." -DCMAKE_INSTALL_PREFIX=/usr \
             -DCMAKE_BUILD_TYPE=Release \
             -DBUILD_WERROR=OFF \
             -DSTATIC_SQLITE=ON
  make 
}

package(){
  cd ${srcdir}/${_pkgname}/build
  make DESTDIR=${pkgdir} install
}