#
# Chakra Packages for Chakra, part of chakra-project.org
#

pkgname=qgis
pkgver=1.7.1
pkgrel=1
pkgdesc='A Geographic Information System (GIS) that supports vector, raster & database formats.'
url='http://qgis.org/'
license=('GPL')
arch=('i686' 'x86_64')
depends=('libmysqlclient' 'postgresql-libs' 'sqlite3' 'jasper' 'curl' 'qt' 'python2' 'pyqt' 'giflib' 'xerces-c' 'cfitsio' 'qwt' 'gdal' 'flex' 'bison' 'graphviz')
makedepends=('grass' 'gsl' 'postgis' 'netcdf' 'cmake' 'fcgi' 'sip')
optdepends=('postgis: postgis support and SPIT plugin'
            'fcgi: qgis mapserver'
            'sip: python-support'
            'grass: grass plugin'
            'gsl: georeferencer  ')
options=('!makeflags')
source=("http://qgis.org/downloads/${pkgname}-${pkgver}.tar.bz2"
        'qgis.desktop')
md5sums=('677dcb9d0d53cc7c2a6451590a362477'
         '8ab66039f2aba519b92f52272ec3c13e')

build() {
	cd ${srcdir}
	rm -rf build
	mkdir build
	cd build

	cmake ../${pkgname}-${pkgver} \
		-DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_SKIP_RPATH=ON \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DGRASS_PREFIX=/opt/grass \
		-DQGIS_MANUAL_SUBDIR=share/man
	make
}

package() {
	cd build
	make DESTDIR=${pkgdir} install
	# install some freedesktop.org compatibility
	install -D -m644 ${srcdir}/${pkgname}.desktop \
	${pkgdir}/usr/share/applications/${pkgname}.desktop
}