# Include global configuration
source ../kdeapps.conf

pkgname="umbrello"
arch=('x86_64')
pkgver=${_kdever}
pkgrel=1
pkgdesc="An UML modeling tool for KDE"
screenshot="http://uml.sourceforge.net/screenshots/umbrello-2.0.png"
url="http://www.kde.org"
license=('GPL' 'LGPL' 'FDL')
depends=(hicolor-icon-theme ktexteditor kinit)
makedepends=(extra-cmake-modules kdoctools python3)
groups=('kde' 'kde-devel' 'kde-uninstall' 'kdesdk')
provides=('kdesdk-umbrello')
conflicts=('kdesdk-umbrello')
replaces=('kdesdk-umbrello')
install=kdesdk.install
options=('docs' 'debug')
source=("$_mirror/${pkgname}-$_kdever.tar.xz"
        0001-Add-AppStream-metadata.patch)
sha256sums=(`grep ${pkgname}-$_kdever.tar.xz  ../checksums.txt | cut -d " " -f1`
            'f3b2fa086f1952c622f669bdf413c05144ae789ac7c8105ac6d94051b3ec3467')

prepare() {
  mkdir -p build
  
  cd $pkgname-$pkgver
  # patch to fix install process
  # https://bugs.kde.org/show_bug.cgi?id=352607
  patch -p1 -i ../0001-Add-AppStream-metadata.patch
}

build() {
  cd build
  cmake_kf5 ../${pkgname}-${pkgver} \
              -DBUILD_KF5=ON
  make
}

package() {
    cd build
    make DESTDIR=${pkgdir} install
}