pkgname=bomi
pkgver=0.9.11.r39.g5f0cc0a7
pkgrel=2
pkgdesc="Powerful and easy-to-use multimedia player"
arch=('x86_64')
url="http://bomi-player.github.io"
license=('GPL2')
screenshot='http://i.imgur.com/j76hzyd.png'
depends=('qt5-base' 'qt5-declarative' 'qt5-x11extras' 'qt5-quickcontrols' 'qt5-svg'
         'libdvdread' 'libdvdnav' 'libcdio-paranoia' 'libcdio' 'smbclient'
         'alsa-lib' 'libpulse' 'jack' 'libchardet' 'libbluray'
         'libva' 'libgl' 'fribidi' 'libass' 'ffmpeg')
makedepends=('mesa' 'gcc' 'pkg-config' 'python3' 'qt5-tools')
optdepends=('libaacs: AACS decryption for Blu-ray support'
            'libbdplus: BD+ decryption for Blu-ray support'
            'youtube-dl: streaming website support including YouTube'
            'yle-dl:  rtmpdump frontend for Yle servers'
            'mesa-vdpau: hardware acceleration for nvidia')
provides=('cmplayer')
replace=('cmplayer')
conflicts=('cmplayer' 'bomi-git')
source=(git+https://github.com/d-s-x/${pkgname}.git
        qml_internal_types.patch)
md5sums=('SKIP'
         '119bfa72cf4700c16c11c2b3ec8d8865')

pkgver() {
    cd "$srcdir/$pkgname"
    echo $(git describe --tags | sed -E 's/([^-]*-g)/r\1/;s/-/./g' | cut -c2-)
}

build() {
  cd "$srcdir/$pkgname"
    ./configure --prefix=/usr \
        --defaultskin=Breeze

  # Temporary fix until the upstream is fixed.
    if ! grep PlayInfoText ./src/bomi/imports/bomi/qmldir; then
      patch -p1 -i "$srcdir/qml_internal_types.patch"
    fi

  make
}

package() {
  cd "$srcdir/$pkgname"
  make DEST_DIR=$pkgdir install
}