pkgbase=qtkeychain
pkgname=('qtkeychain-qt4' 'qtkeychain-qt5')
pkgver=0.5.0
pkgrel=2
pkgdesc="Provides support for secure credentials storage."
arch=('x86_64')
url="https://github.com/frankosterfeld/qtkeychain"
license=('BSD')
makedepends=('cmake' 'icu' 'qt5-tools' 'qt')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/frankosterfeld/$pkgbase/archive/v${pkgver}.tar.gz")
md5sums=('ed813a5db320883c2cf34db16a72b2a1')

prepare() {
    mkdir -p build{4,5}
}

build() {
    cd build4
    cmake ../$pkgbase-$pkgver \
          -DBUILD_WITH_QT4=ON \
          -DCMAKE_INSTALL_PREFIX=/usr \
          -DCMAKE_INSTALL_LIBDIR=lib \
          -DCMAKE_INSTALL_LIBEXECDIR=lib/${pkgname} \
          -DCMAKE_BUILD_TYPE=Release
    make
    
    cd ../build5
    cmake ../$pkgbase-$pkgver \
          -DCMAKE_INSTALL_PREFIX=/usr \
          -DCMAKE_INSTALL_LIBDIR=lib \
          -DCMAKE_INSTALL_LIBEXECDIR=lib/${pkgname} \
          -DCMAKE_BUILD_TYPE=Release
    make
}

package_qtkeychain-qt4() {
    depends=('qt')
    provides=('qtkeychain')
    replaces=('qtkeychain')

    cd build4
    make DESTDIR="$pkgdir" install
    install -Dm644 "$srcdir"/$pkgbase-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_qtkeychain-qt5() {
    depends=('qt5-base')

    cd build5
    make DESTDIR="$pkgdir" install
    install -Dm644 "$srcdir"/$pkgbase-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}