pkgname=icedtea-web
pkgver=1.7
pkgrel=1
arch=('x86_64')
pkgdesc="Provides a Free Software web browser plugin running applets written in the Java programming language and an implementation of Java Web Start, originally based on the NetX project."
url="http://icedtea.classpath.org/wiki/IcedTea-Web"
license=('GPL2')

_javaver=8
_jvmdir="/usr/lib/jvm/java-${_javaver}-openjdk"

depends=("java-environment=${_javaver}" 'qt' 'desktop-file-utils')
makedepends=('zip' 'npapi-sdk' 'rhino' 'junit' 'cups' 'autoconf')
optdepends=('rhino: for using proxy auto config files')
categories=('network')
install="${pkgname}.install"
source=("http://icedtea.classpath.org/download/source/${pkgname}-${pkgver}.tar.gz")
# due to broken path names in the tarball that fails with LANG=C in our chroot
noextract="${pkgname}-$pkgver.tar.gz"
md5sums=('63bcda2c106e1a7e79afc7e9c9cb0a47')

prepare() {
  cd "${srcdir}"

  # if you encounter this error "bsdtar: Failed to set default locale"
  # you will need to set locale of your chroot   https://wiki.archlinux.org/index.php/Locale
  # do this (inside your chroot):
  # sudo nano /etc/locale.gen
  # then uncomment a locale (like en_US.UTF-8 for example)
  # save and type
  # sudo locale-gen

  LANG=en_US.UTF-8 bsdtar -x -f "${srcdir}/${pkgname}-$pkgver.tar.gz"
}

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}

  ./configure --prefix="${_jvmdir}" \
              --with-jdk-home="${_jvmdir}" \
              --datarootdir=/usr/share \
              --disable-docs

  make
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}

  # possible make target (see bottom of Makefile.am: install-exec-local install-data-local
  make install-exec-local install-data-local DESTDIR="${pkgdir}"

  # Install desktop files.
  install -dm755 "${pkgdir}/usr/share"/{applications,pixmaps}
  install -m644 javaws.png "${pkgdir}/usr/share/pixmaps"
  install -m644 {javaws,itweb-settings}.desktop "${pkgdir}/usr/share/applications"

  # link binaries into /usr/bin + jre/bin
  install -m755 -d "${pkgdir}/usr/bin"
  install -m755 -d "${pkgdir}/${_jvmdir}/jre/bin"
  pushd "${pkgdir}/${_jvmdir}/bin"
    for file in *; do
      ln -sf "${_jvmdir}/bin/${file}" "${pkgdir}/usr/bin"
      ln -sf "${_jvmdir}/bin/${file}" "${pkgdir}/${_jvmdir}/jre/bin"
    done
  popd

  # link the mozilla-plugin - test it here http://www.java.com/en/download/help/testvm.xml
  install -dm755 "${pkgdir}/usr/lib/mozilla/plugins/"
  ln -sf "${_jvmdir}/lib/IcedTeaPlugin.so" "${pkgdir}/usr/lib/mozilla/plugins/"
  
  make DESTDIR="${pkgdir}" install-data-local
}