# Contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/gwenview
source ../kdeapps.conf

pkgname=gwenview
pkgver=${_kdever}
pkgrel=1
pkgdesc="A fast and easy to use image viewer for KDE"
arch=('x86_64')
url="http://kde.org/applications/graphics/gwenview/"
screenshot="https://www.kde.org/images/screenshots/gwenview.png"
license=('GPL' 'LGPL' 'FDL')
depends=('kded' 'kactivities-frameworks' 'libkdcraw' 'libkipi' 'baloo-kf5' 'lcms2' 'exiv2')
makedepends=('extra-cmake-modules' 'kdoctools' 'python3')
optdepends=('qt5-imageformats: support for tiff, webp, and more image formats'
            'kimageformats: support for dds, xcf, exr, psd, and more image formats')
install=${pkgname}.install
groups=('kde' 'kde-uninstall' 'kde-applications' 'kdegraphics')
provides=('kdegraphics-gwenview')
replaces=('kdegraphics-gwenview')
conflicts=('kdegraphics-gwenview')
source=("$_mirror/${pkgname}-$_kdever.tar.xz"{,.sig})
sha256sums=(`grep ${pkgname}-$_kdever.tar.xz  ../kdeapps.sums | cut -d " " -f1`
                        'SKIP')
validpgpkeys=(${Avalidpgpkeys[@]})

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake_kf5 ../${pkgname}-${pkgver} \
  -DGWENVIEW_SEMANTICINFO_BACKEND="Baloo"
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}