#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>
# contributor (x86_64): Giuseppe Calà <jiveaxe@gmail.com>

pkgname=tellico
pkgver=2.3.5
pkgrel=1
pkgdesc="A collection manager for KDE"
arch=('i686' 'x86_64')
url="http://tellico-project.org/"
license=('GPL')
depends=('kde-workspace' 'yaz' 'exempi' 'libksane' 'taglib'
         'kdemultimedia-common' 'poppler-qt' 'qjson')
makedepends=('automoc4' 'cmake' 'docbook-xsl')
categories=('office')
install=$pkgname.install
source=("http://tellico-project.org/files/${pkgname}-${pkgver}.tar.bz2")
md5sums=('e6a1835d2622b79c4bfd95271bce858e')

build() {
  cd "${srcdir}"
  mkdir build
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr

  make
}

package() {
  cd "${srcdir}"/build
  make DESTDIR="${pkgdir}" install

  # fix python 2.7 path
  find "$pkgdir" -iname "*.py" | xargs sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|'
}