# Maintainer: Daniele Cocca <jmc@chakra-project.org>

pkgbase=requests
pkgname=("python2-${pkgbase}" "python3-${pkgbase}")
pkgver=1.1.0
pkgrel=1
pkgdesc="Requests is an Apache2 Licensed HTTP library, written in Python, for human beings."
arch=('any')
url="http://python-requests.org/"
license=('APACHE')
makedepends=('python2' 'python3')
source=("python-requests-${pkgver}.tar.gz"::"https://github.com/kennethreitz/requests/tarball/v${pkgver}")
md5sums=('89b4958831c4c3276ffe5d21ed53dec8')

build() {
  # Start the Python 2.x build
  cd "${srcdir}"
  rm -rf "python2-requests-${pkgver}/"
  cp -r kennethreitz-requests-*/ "python2-requests-${pkgver}/"

  cd "python2-requests-${pkgver}"
  python2 setup.py build

  # Start the Python 3.x build
  cd "${srcdir}"
  rm -rf "python3-requests-${pkgver}/"
  cp -r kennethreitz-requests-*/ "python3-requests-${pkgver}/"

  cd "python3-requests-${pkgver}"
  python3 setup.py build
}

package_python2-requests() {
depends=('python2')

  cd "${srcdir}/python2-requests-${pkgver}"
  python2 setup.py install --prefix="${pkgdir}"
}

package_python3-requests() {
depends=('python3')

  cd "${srcdir}/python3-requests-${pkgver}"
  python3 setup.py install --prefix="${pkgdir}"
}

# vim:set ts=2 sw=2 et: