#
# Apps Packages for Chakra, part of chakra-project.org
#
# maintainer abveritas@chakra-project.org

pkgname=conky
pkgver=1.9.0
pkgrel=2
pkgdesc="An advanced, highly configurable system monitor for X based on torsmo"
arch=('x86_64')
url="http://conky.sourceforge.net/"
license=('custom')
replaces=('torsmo')
depends=('glib2' 'curl' 'lua' 'wireless_tools' 'libxml2' 'libxft' 'libxdamage' 'imlib2')
makedepends=('docbook2x')
categories=('utils')
backup=(etc/conky/conky.conf etc/conky/conky_no_x11.conf)
source=(http://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.bz2)
md5sums=('d3de615f43aadc98d555e05ad9e902c2')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  CPPFLAGS="${CXXFLAGS}" LIBS="${LDFLAGS}" ./configure \
              --prefix=/usr \
              --sysconfdir=/etc \
              --enable-curl \
              --enable-wheather-xoap \
              --enable-wlan \
              --enable-rss \
              --enable-ibm \
              --enable-imlib2
  make 
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install 
  install -D -m644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
}