pkgname=kmymoney
pkgver=5.0.0
pkgrel=1
pkgdesc="A finance manager for KDE4 with HBCI support"
arch=('x86_64')
url="https://kmymoney.org/"
license=('GPL')
depends=('aqbanking' 'boost-libs' 'libalkimia' 'sqlcipher' 'qt5-base' 'qgpgme' 'karchive'
         'kcoreaddons' 'kconfig' 'kwidgetsaddons' 'ki18n' 'kcompletion' 'kcmutils'
         'kitemmodels' 'kitemviews' 'kservice' 'kwallet' 'kiconthemes' 'kxmlgui'
         'ktextwidgets' 'knotifications' 'kio' 'kdoctools' 'kholidays' 'kcontacts'
         'akonadiconsole' 'kross' 'kqtquickcharts' 'kdiagram' 'kdewebkit' 'shared-mime-info')
makedepends=('boost' 'extra-cmake-modules' 'doxygen')
categories=('office')
install=$pkgname.install
source=(https://download.kde.org/stable/$pkgname/$pkgver/src/$pkgname-$pkgver.tar.xz)
sha256sums=('984f5866aa7d7bf53d2ef9bbfbb6e5de0d69972f225031ebfd86b46df131f5ba')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  mkdir -p build
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}/build"
  cmake ../ \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_BUILD_TYPE=RELEASE \
    -DCMAKE_SKIP_RPATH=YES \
    -Wno-dev
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}/build"

  make DESTDIR="${pkgdir}" install
}