#
# Games Packages for Chakra, part of chakra-project.org
#
# Maintainer: Adrián Chaves Fernández (Gallaecio) <adriyetichaves gmail.com>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=crypto++
_pkgname=cryptopp
pkgver=5.6.1
_pkgver=561
pkgrel=2
pkgdesc="C++ class library of cryptographic schemes."
arch=('i686' 'x86_64')
url="http://www.cryptopp.com"
license=('custom')
makedepends=('unzip')
source=("${url}/${_pkgname}${_pkgver}.zip"
        'libcrypto++.pc')
md5sums=('96cbeba0907562b077e26bcffb483828'
         '2337c6edbc552d9142cae8e0854715e7')

build() {
  cd "${srcdir}"

  sed -i -e 's/^CXXFLAGS/#CXXFLAGS/' GNUmakefile
  export CXXFLAGS="${CXXFLAGS} -DNDEBUG -fPIC"
  make -f GNUmakefile
  make libcryptopp.so
}

package() {
  install -d "${pkgdir}/usr"/{lib/pkgconfig,include/cryptopp}
  install -m644 *.h "${pkgdir}/usr/include/${_pkgname}"
  install -m644 libcryptopp.a "${pkgdir}/usr/lib"
  install -m644 libcryptopp.so "${pkgdir}/usr/lib"
  install -m644 "${srcdir}/libcrypto++.pc" "${pkgdir}/usr/lib/pkgconfig/libcrypto++.pc"

  # License:
  install -D -m644 License.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim:set ts=2 sw=2 et: