# Contributions from Arch: https://www.archlinux.org/packages/extra/x86_64/kdegraphics-svgpart/
# Include global configuration
source ../kdeapps.conf

pkgname=kdegraphics-svgpart
_pkgname=svgpart
pkgver=${_kdever}
pkgrel=1
pkgdesc="A KPart for viewing SVGs"
arch=('x86_64')
url='https://projects.kde.org/projects/kde/kdegraphics/svgpart'
license=('GPL' 'LGPL' 'FDL')
depends=("kdelibs>=${_libsver}")
makedepends=('pkg-config' 'cmake' 'automoc4')
groups=('kde' 'kdegraphics' 'kde-uninstall')
provides=('svgpart')
options=('docs' 'debug')
source=("$_mirror/${_pkgname}-$_kdever.tar.xz")
sha256sums=(`grep ${_pkgname}-$_kdever.tar.xz  ../checksums.txt | cut -d " " -f1`)

build() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    cmake . \
        -DCMAKE_BUILD_TYPE=${_build_type} \
        -DCMAKE_INSTALL_PREFIX=${_installprefix} \
        -DCMAKE_SKIP_RPATH=ON \
        -DKDE4_BUILD_TESTS=ON \
        -DCMAKE_{SHARED,MODULE,EXE}_LINKER_FLAGS='-Wl,--no-undefined -Wl,--as-needed'
    make
}

package() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    make DESTDIR=${pkgdir} install
}