# Contributions from Arch: https://www.archlinux.org/packages/extra/x86_64/kdegames-klines/
# Include global configuration

pkgname=klines
pkgver=18.08.1
pkgrel=1
pkgdesc="A simple but highly addictive, one player game"
arch=('x86_64')
url='http://kde.org/applications/games/klines/'
screenshot='https://www.kde.org/images/screenshots/klines.png'
license=('GPL' 'LGPL' 'FDL')
depends=('libkdegames')
makedepends=('cmake' 'extra-cmake-modules' 'python' 'kdoctools')
groups=('kde' 'kde-uninstall' 'kde-applications' 'kdegames')
replaces=('kdegames-klines')
conflicts=('kdegames-klines')
options=('docs' 'debug')
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('2cbf40c6025676a46b83ee7822fd68ac8b211d2de65dee871e4076a8f9fe9bf3'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
  cd build
  make DESTDIR=${pkgdir} install
}