### Remember to check if qmmp-plugin-pack needs to update ### 
 
pkgname=qmmp
pkgver=1.1.1
pkgrel=1
pkgdesc="Qt based audio-player"
arch=('x86_64')
url="http://qmmp.ylsoftware.com/"
license=('GPL')
depends=('alsa-lib' 'curl' 'hicolor-icon-theme' 'libmad' 'libvorbis' 'libogg'  'qt5-base' 'qt5-tools' 
	 'qt5-x11extras' 'qt5-multimedia' 'taglib' 'xdg-utils')
makedepends=('cmake'  'flac' 'jack' 'libmpcdec' 'ffmpeg' 'libsamplerate' 'libmodplug' 'libsndfile' 
             'wavpack' 'libcdio' 'mesa' 'faad2' 'libgme' 'libcddb' 'libmms' 'wildmidi')
optdepends=('flac: native FLAC support'
            'jack: JACK sound output'
            'oss: OSS sound output'
            'pulseaudio: PulseAudio output'
            'libmpcdec: Musepack support'
            'libmodplug: MOD playing library'
            'libsndfile: sampled sound support'
            'libcdio: for audio CD playback support'
            'faad2: ADTS AAC support'
            'libgme: support for chiptunes from various platforms'
            'libcddb: CDDB server support'
            'libmms: MMS stream protocol support'
            'ffmpeg' 'libsamplerate' 'wavpack')
categories=('multimedia')
screenshot=('http://qmmp.ylsoftware.com/images/qmmp-0.3.0_full_1.png')
install=$pkgname.install
source=("$pkgname-$pkgver::http://qmmp.ylsoftware.com/files/$pkgname-$pkgver.tar.bz2")
sha256sums=('c82364b76d23d8bba52466737349493593802576bee57979553a3de67163b518')

build() {
  cd ${srcdir}/$pkgname-$pkgver

  cmake . -DCMAKE_INSTALL_PREFIX=/usr \
	  -DLIB_DIR=lib \
	  -DUSE_HAL:BOOL=FALSE
  make
}

package() {
  cd ${srcdir}/$pkgname-$pkgver

  make DESTDIR=${pkgdir} install
}