# Apps Packages for Chakra, part of www.chakra-project.org
# Maintainer: H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Stephen McIntosh <stephenmac7[at]gmail[dot]com>
#               Thomas Dziedzic <gostrc@gmail.com>
#               Vesa Kaihlavirta <vesa@archlinux.org>
#               Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=regex-base
pkgname=haskell-regex-base
pkgver=0.93.2
pkgrel=7
pkgdesc="Replaces/Enhances Text.Regex"
url="http://hackage.haskell.org/package/regex-base"
license=('custom:BSD3')
arch=('x86_64' 'i686')
makedepends=()
depends=('ghc=7.6.3-1' 'haskell-array' 'haskell-base>=3.0' 'haskell-bytestring' 'haskell-containers' 'haskell-mtl')
options=('strip')
source=("http://hackage.haskell.org/packages/archive/regex-base/0.93.2/regex-base-0.93.2.tar.gz")
install="haskell-regex-base.install"
sha512sums=('4f6269cb1c1fefa2164d999e2e787118edc5fd88e356535e50f143d0b98de4fa1854959955e183aed27a77335b81063a2385bb6bdeb8cb80e7fdd812ab96d22a')

build() {
    cd "${srcdir}/regex-base-0.93.2"
    runhaskell Setup configure \
        -O \
        ${PKGBUILD_HASKELL_ENABLE_PROFILING:+-p } \
        --enable-split-objs \
        --enable-shared \
        --prefix="/usr" \
        --docdir="/usr/share/doc/haskell-regex-base" \
        --libsubdir='$compiler/site-local/$pkgid'
    runhaskell Setup build
    runhaskell Setup haddock
    runhaskell Setup register   --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
    cd "${srcdir}/regex-base-0.93.2"
    install -D -m744 register.sh \
        "${pkgdir}/usr/share/haskell/haskell-regex-base/register.sh"
    install -m744 unregister.sh \
        "${pkgdir}/usr/share/haskell/haskell-regex-base/unregister.sh"
    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"

    # Documentation
    ln -s "/usr/share/doc/haskell-regex-base/html" \
        "${pkgdir}/usr/share/doc/ghc/html/libraries/regex-base"

    # License
    install -D -m644 LICENSE \
        "${pkgdir}/usr/share/licenses/haskell-regex-base/LICENSE"
    rm -f "${pkgdir}/usr/share/doc/haskell-regex-base/LICENSE"

    runhaskell Setup copy --destdir="${pkgdir}"
}