# Maintainer: UtG  <utg[dot]chakra.linux[at]gmail[dot]com>

pkgname=waf
pkgver=1.7.16
pkgrel=1
pkgdesc='General-purpose build system modelled after Scons'
url='http://code.google.com/p/waf/'
arch=('x86_64')
license=('BSD')
depends=('python3')
makedepends=('setconf')
provides=('python3-waf')
options=('!emptydirs')
source=("http://ftp.waf.io/pub/release/$pkgname-$pkgver.tar.bz2")
sha256sums=('ec12c8a4df1e7900afa5df117a48467a41bd81e951aca9f160394ddda53e5435')

prepare() {
  cd "$pkgname-$pkgver"

  # Extracting license
  head -n 30 waf | tail -n 25 > LICENSE
  # Python 3 fix
  sed -i '0,/env python/s//python3/' waf
}

build() {
  cd "$pkgname-$pkgver"

  ./waf-light configure --prefix=/usr
  ./waf-light --make-waf
}

package() {
  cd "$pkgname-$pkgver"

  ./waf-light install -f --destdir="$pkgdir" \
    --tools='compat,compat15,ocaml,go,cython,scala,erlang,cuda,gcj,boost,pep8,eclipse'

  install -Dm755 waf "$pkgdir/usr/bin/waf"

  # Force the generation of .waf.admin files
  cd demos/c
  "$pkgdir/usr/bin/waf" configure build >& /dev/null
  cd ../..

  # Fix weird directory placement (FS#38216, FS#38300)
  mkdir -p "$pkgdir/usr/lib/waf"
  mv "$pkgdir/usr/bin/.waf-$pkgver-"* "$pkgdir/usr/lib/waf/"
  setconf "$pkgdir/usr/bin/waf" base '"/usr/lib/waf"'

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}