# Maintainer: Manuel 'UtG' <utg[dot]chakra.linux[at]gmail[dot]com>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=screen
pkgver=4.2.1
pkgrel=1
_ptygroup=5 #the UID of our PTY/TTY group
pkgdesc="Full-screen window manager that multiplexes a physical terminal"
arch=('x86_64')
url="http://www.gnu.org/software/screen/"
license=('GPL')
depends=('ncurses' 'pam')
backup=('etc/screenrc' 'etc/pam.d/screen')
options=('!makeflags')
groups=('system')
install=screen.install
source=("http://ftp.gnu.org/gnu/screen/screen-${pkgver}.tar.gz"{,.sig}
	      screen.pam)
md5sums=('419a0594e2b25039239af8b90eda7d92'
         'SKIP'
         '74f7919d7b65436cc2ea5341fa8ca374')

build() {
  #export LDFLAGS="${LDFLAGS} -Wl,--as-needed"

  cd "${srcdir}/${pkgname}-${pkgver}"
  
  ./configure \
		  --prefix=/usr \
		  --enable-pam \
		  --enable-colors256 \
		  --enable-rxvt_osc \
		  --enable-telnet \
		  --with-pty-group=$_ptygroup \
		  --mandir=/usr/share/man \
		  --infodir=/usr/share/info \
		  --with-socket-dir=/run/screens \
		  --with-sys-screenrc=/etc/screenrc \
		  
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  
  make DESTDIR="${pkgdir}" install
  
  install -Dm644 ${srcdir}/screen.pam ${pkgdir}/etc/pam.d/screen

  install -Dm644 etc/completer.zsh ${pkgdir}/usr/share/zsh/site-functions/screen
  install -Dm644 etc/etcscreenrc ${pkgdir}/etc/screenrc
  install -Dm644 etc/screenrc ${pkgdir}/etc/skel/.screenrc

  #gzip -9 ${pkgdir}/usr/share/info/*
}