# Maintainer: Neophytos Kolokotronis <tetris4 AT gmail DOT com>
# contributor: abveritas@chakra-project.org

pkgname=qlandkartegt
pkgver=1.7.6
pkgrel=1
pkgdesc="Use your GPS with Linux"
screenshot="http://sourceforge.net/dbimage.php?id=176174"
arch=('x86_64')
url="http://www.qlandkarte.org"
license=('GPL')
depends=('gdal' 'gpsd' 'libdmtx' 'libexif' 'libmysqlclient' 'mesa' 'postgresql-libs'
         'qt' 'shared-mime-info' 'qtwebkit' 'unixodbc')
makedepends=('cmake')
categories=('utils')
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz"
        'qlandkartegt-mimetypes.xml')
md5sums=('4213da3ad94bda19a77db91617edd152'
         'e4808690a9b5381880c573abd81cffdd')

build() {
  cd ${srcdir}/$pkgname-$pkgver

  install -d ${srcdir}/$pkgname-$pkgver/build
  cd ${srcdir}/$pkgname-$pkgver/build

  cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release ..
  make
}

package(){
  cd ${srcdir}/$pkgname-$pkgver/build

  make DESTDIR=${pkgdir} install

  install -D -m644 ${srcdir}/$pkgname-mimetypes.xml \
    ${pkgdir}/usr/share/mime/packages/$pkgname-mimetypes.xml
}