# Include global configuration

pkgname=kajongg
pkgver=18.12.2
pkgrel=1
pkgdesc="The ancient Chinese board game for 4 players"
arch=('x86_64')
url='http://kde.org/applications/games/kajongg/'
license=('GPL' 'LGPL' 'FDL')
depends=(python3-twisted python3-pyqt5 libkmahjongg hicolor-icon-theme qt5-svg)
makedepends=(extra-cmake-modules kdoctools)
groups=("kde" "kdegames" "kde-uninstall")
conflicts=(kdegames-kajongg)
replaces=(kdegames-kajongg)
provides=(kdegames-kajongg)
options=('docs' 'debug')
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('2962e7328f1556858bb73f6d7c065db517176442db869f405e96cbbd163262bf'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
  cd build
  make DESTDIR=${pkgdir} install
}