# Contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/kalgebra

pkgname=kalgebra
pkgver=18.12.2
pkgrel=1
pkgdesc="Graph calculator"
url="http://kde.org/applications/education/kalgebra/"
screenshot="https://www.kde.org/images/screenshots/kalgebra.png"
arch=('x86_64')
license=('GPL' 'LGPL' 'FDL')
depends=('analitza' 'kio' 'qt5-webkit' 'hicolor-icon-theme' 'qt5-webengine' 'lcms2')
makedepends=('extra-cmake-modules' 'kdoctools' 'python3' 'glu')
provides=('kdeedu-kalgebra')
replaces=('kdeedu-kalgebra')
conflicts=('kdeedu-kalgebra')
groups=("kde" "kdeedu" "kde-uninstall")
categories=('education')
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('6227f38b02dac50498b5488067cdbf02bd833307cd083f6be15585cb2828e5f8'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@" 
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}