# Include global configuration
source ../kdeapps.conf

pkgname=kdevplatform
pkgver=$_kdevver
pkgrel=1
pkgdesc='A C/C++ development platform for KDE'
arch=(x86_64)
url='http://www.kdevelop.org/'
license=(GPL)
option=('debug')
depends=(grantlee-qt5 hicolor-icon-theme kcmutils threadweaver kitemmodels ktexteditor knotifyconfig knewstuff libkomparediff2 qt5-webkit)
makedepends=(extra-cmake-modules boost subversion)
optdepends=('subversion: Subversion plugin')
install="$pkgname.install"
source=("http://download.kde.org/stable/kdevelop/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.asc})
sha256sums=("`grep ${pkgname}-${pkgver}.tar.xz  ../kdevelop.checksums | cut -d " " -f1`"
            'SKIP')
validpgpkeys=('329FD02C5AA48FCC77A4BBF0AC44AC6DB29779E6')

prepare() {
  mkdir -p build

  sed -i 's|qdbus|qdbus-qt5|g' "${pkgname}-${pkgver}/util/kdevplatform_shell_environment.sh"
}

build() {
  cd build 
  cmake_kf5 ../${pkgname}-${pkgver}
  make 
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}