# Contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/kig

pkgname=kig
pkgver=18.08.1
pkgrel=1
pkgdesc="Interactive geometry"
url="http://kde.org/applications/education/kig/"
screenshot="https://www.kde.org/images/screenshots/kig.png"
arch=('x86_64')
license=('GPL' 'LGPL' 'FDL')
depends=('ktexteditor' 'kdelibs4support')
makedepends=('extra-cmake-modules' 'kdoctools' 'python3' 'boost')
conflicts=('kdeedu-kig')
provides=('kdeedu-kig')
replaces=('kdeedu-kig')
groups=("kde" "kdeedu" "kde-uninstall")
categories=('education')
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('e23c517e8caf42ec369fafd2dd1047045042d2fcccf91e9d02d1f91679104ec1'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@" 
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install

  # Use the python2 executable
  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' "${pkgdir}"/usr/bin/pykig.py
}