# Maintainer:   H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Manuel Tortosa <manutortosa@chakra-project.org>

pkgname=akonadi
pkgver=1.11.0
pkgrel=5
pkgdesc="PIM layer, which provides an asynchronous API to access all kinds of PIM data"
arch=('x86_64')
url='http://www.akonadi-project.org'
license=('LGPL')
depends=('shared-mime-info'
         'boost-libs'
         'akonadi-backend'
         'soprano>=2.7.56')
makedepends=('pkg-config'
             'cmake'
             'automoc4'
             'boost'
             'postgresql')
install=$pkgname.install
source=("http://download.kde.org/stable/akonadi/src/${pkgname}-${pkgver}.tar.bz2")
sha512sums=('366f0e4a86038af5eb6603653e599076c66e84f59db57f4c56a89ec265be7e335f3f5d14444030a6f398e2361969ad85bc73357359da7ab8c307ec3c5d80ea40')

prepare() {
    mkdir "${srcdir}/build"
}

build() {
    cd "${srcdir}/build"
    cmake ../${pkgname}-${pkgver} \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DINSTALL_QSQLITE_IN_QT_PREFIX=TRUE
    make 
}

package() {
    cd ${srcdir}/build
    make DESTDIR=${pkgdir} install
}