# Maintainer:   H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Manuel Tortosa <manutortosa@chakra-project.org>

# Include global configuration
source ../kdeapps.conf

pkgname=kdebindings-qtruby
_pkgname=qtruby
pkgver=${_oldkdever}
pkgrel=2
pkgdesc="Qt bindings for ruby"
url="http://kde.org/"
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
depends=("kdebindings-smokeqt>=${_oldkdever}" "ruby")
makedepends=('cmake' 'automoc4' "kdebindings-smokegen>=${_oldkdever}")
conflicts=('kdebindings-common')
groups=("kde" "kdebindings" "kde-uninstall")
provides=('qtruby')
options=('docs' '!header' 'debug' 'log')
source=("$_oldkdemirror/${_pkgname}-$_oldkdever.tar.xz")
sha256sums=(`grep ${_pkgname}-$_oldkdever.tar.xz  ../checksums.txt | cut -d " " -f1`)

prepare() {
    # RUBY_VERSION_PATCH doesn't exist with ruby 2.1, and this means that cmake tries to parse + ) instead of + somenumber)
    sed -i 's/\${RUBY_VERSION_PATCH}/0/g'  "${srcdir}/${_pkgname}-${pkgver}"/CMakeLists.txt
}

build() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    cmake . \
        -DCMAKE_BUILD_TYPE=${_build_type} \
        -DCMAKE_INSTALL_PREFIX=${_installprefix} 
    make
}

package() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    make DESTDIR=${pkgdir} install
}