# Contributions from Arch: https://www.archlinux.org/packages/extra/x86_64/telepathy-kde-integration-module/
# Include global configuration

pkgname=ktp-kded-module
pkgver=18.12.1
pkgrel=1
pkgdesc="Workspace integration module - provides several plugins like auto-away, the infamous 'Now listening to...' and also an error handler"
arch=('x86_64')
url="https://community.kde.org/Real-Time_Communication_and_Collaboration"
license=('GPL')
depends=('ktp-common-internals' 'kidletime' 'kactivities')
makedepends=('extra-cmake-modules' 'kdoctools' 'python3')
provides=('ktp-kded-integration-module')
replaces=('ktp-kded-integration-module')
conflicts=('ktp-kded-integration-module')
groups=('kde-telepathy')
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('faf35ef3093483a07f2f1798fe919a2afe34600ec7e08bfff0b993e5e245bc4e'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
    cd build
    make DESTDIR=${pkgdir} install
}