# Apps Packages for Chakra, part of www.chakra-project.org
# Maintainer: H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Stephen McIntosh <stephenmac7[at]gmail[dot]com>
#               Thomas Dziedzic <gostrc@gmail.com>
#               Vesa Kaihlavirta <vesa@archlinux.org>
#               Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=hashed-storage
pkgname=haskell-hashed-storage
pkgver=0.5.10
pkgrel=3
pkgdesc="Hashed file storage support code"
url="http://hackage.haskell.org/package/hashed-storage"
license=('custom:BSD3')
arch=('x86_64' 'i686')
makedepends=()
depends=('ghc=7.6.3-1' 'haskell-base>=4.0' 'haskell-binary' 'haskell-bytestring' 'haskell-containers' 'haskell-dataenc' 'haskell-directory' 'haskell-extensible-exceptions' 'haskell-filepath' 'haskell-mmap>=0.5.0' 'haskell-mtl' 'haskell-zlib')
options=('strip')
source=("http://hackage.haskell.org/packages/archive/hashed-storage/0.5.10/hashed-storage-0.5.10.tar.gz")
install="haskell-hashed-storage.install"
sha512sums=('dfb9cecdfe44e311020ccb79c437d2bb326f18d4022a0386aacd5c23a7c93b6a4f70baa7c2724b796785257a1733407975682fd3b949eda80bee9824df9b7001')

build() {
    cd "${srcdir}/hashed-storage-0.5.10"
    runhaskell Setup configure \
        -O \
        ${PKGBUILD_HASKELL_ENABLE_PROFILING:+-p } \
        --enable-split-objs \
        --enable-shared \
        --prefix="/usr" \
        --docdir="/usr/share/doc/haskell-hashed-storage" \
        --libsubdir='$compiler/site-local/$pkgid'
    runhaskell Setup build
    runhaskell Setup haddock
    runhaskell Setup register   --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
    cd "${srcdir}/hashed-storage-0.5.10"
    install -D -m744 register.sh \
        "${pkgdir}/usr/share/haskell/haskell-hashed-storage/register.sh"
    install -m744 unregister.sh \
        "${pkgdir}/usr/share/haskell/haskell-hashed-storage/unregister.sh"
    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"

    # Documentation
    ln -s "/usr/share/doc/haskell-hashed-storage/html" \
        "${pkgdir}/usr/share/doc/ghc/html/libraries/hashed-storage"

    # License
    install -D -m644 LICENSE \
        "${pkgdir}/usr/share/licenses/haskell-hashed-storage/LICENSE"
    rm -f "${pkgdir}/usr/share/doc/haskell-hashed-storage/LICENSE"

    runhaskell Setup copy --destdir="${pkgdir}"
}