#
# Apps Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Andrei Nistor <coder[dot]tux[at]ceata[dot]org>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=rekonq
pkgver=0.9.2
pkgrel=1
pkgdesc='A WebKit based web browser for KDE'
arch=('i686' 'x86_64')
url='http://rekonq.sourceforge.net/'
license=('GPL')
depends=('kdelibs' 'kde-baseapps' 'qt')
makedepends=('cmake' 'automoc4' 'docbook-xsl')
categories=('network')
install=${pkgname}.install
source=(http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2)
md5sums=('5e5ce5fc20f07ac0deb1584404595750')
screenshot=('http://rekonq.kde.org/sites/rekonq.kde.org/files/images/Rekonq-0.6.0.png')

build(){
  cd ${srcdir}

  #Ignore dutch translation cause it was causing issues with 0.9.0
  #sed -i -e "s/add_subdirectory(nl)/#add_subdirectory(nl)/" ${srcdir}/${pkgname}-${pkgver}/doc/CMakeLists.txt

  mkdir -p build 
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -DCMAKE_INSTALL_PREFIX=/usr
  make 
}

package() {
  cd ${srcdir}/build
  make DESTDIR=${pkgdir} install
}