# Contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/kdegraphics-kgamma
# Include global configuration
source ../kdeapps.conf

pkgname=kdegraphics-kgamma
_pkgname=kgamma
pkgver=${_kdever}
pkgrel=1
pkgdesc='A monitor calibration tool'
arch=('x86_64')
url='http://kde.org/applications/graphics/kgamma/'
license=('GPL' 'LGPL' 'FDL')
# Note on libxxf86vm:
#     not detected by namcap because libgl depends on it
#     but nvidia providing libgl does not depend on libxxf86vm
depends=("kde-runtime"
         'libxxf86vm'
         "kdegraphics-libkexiv2>=${_kdever}"
         "kdegraphics-libkdcraw>=${_kdever}"
         "kdegraphics-libkipi>=${_kdever}"
         "kdegraphics-ksaneplugin>=${_kdever}"
         "kdegraphics-thumbnailers>=${_kdever}"
         "kdegraphics-strigi-analyzer>=${_kdever}"
         "kdegraphics-svgpart>=${_kdever}")
makedepends=('cmake' 'automoc4')
groups=('kde' 'kdegraphics' 'kde-uninstall')
categories=('graphics')
provides=('kdegraphics-common')
replaces=('kdegraphics-common'
          'kdegraphics-doc')
conflicts=('kdegraphics-common')
options=('docs' '!header' 'debug' 'log')
source=("$_mirror/${_pkgname}-$_kdever.tar.xz")
sha256sums=(`grep ${_pkgname}-$_kdever.tar.xz  ../checksums.txt | cut -d " " -f1`)

build() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    cmake . \
        -DCMAKE_BUILD_TYPE=${_build_type} \
        -DCMAKE_INSTALL_PREFIX=${_installprefix} \
        -DCMAKE_SKIP_RPATH=ON \
        -DKDE4_BUILD_TESTS=ON \
        -DCMAKE_{SHARED,MODULE,EXE}_LINKER_FLAGS='-Wl,--no-undefined -Wl,--as-needed'
    make
}

package() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    make DESTDIR=${pkgdir} install
}