#
# Apps Packages for Chakra, part of chakra-project.org
#
# Maintainer: Adrián Chaves Fernández (Gallaecio) <adriyetichaves@gmail.com>
# Colaborator: Vesa Kaihlavirta <vesa@archlinux.org>

pkgname=ghc
pkgver=7.0.3
pkgrel=1
pkgdesc="The Glasgow Haskell Compiler"
arch=(i686 x86_64)
url='http://www.haskell.org/ghc/'
license=('BSD')
depends=(gcc 'gmp>=5.0' perl)
makedepends=(dblatex docbook-xsl ghc happy hasktags libxslt)
provides=("haskell-array=0.3.0.2"
          "haskell-bytestring=0.9.1.10"
          "haskell-cabal=1.10.1.0"
          "haskell-containers=0.4.0.0"
          "haskell-directory=1.1.0.0"       
          "haskell-extensible-exceptions=0.1.1.2"
          "haskell-filepath=1.2.0.0"
          "haskell-haskell98=1.1.0.1"
          "haskell-hpc=0.5.0.6"
          "haskell-old-locale=1.0.0.2"
          "haskell-old-time=1.0.0.6"
          "haskell-pretty=1.0.1.2"
          "haskell-process=1.0.1.5"
          "haskell-random=1.0.0.3"
          "haskell-template-haskell=2.5.0.0"
          "haskell-time=1.2.0.3"
          "haskell-unix=2.4.2.0"
         )
replaces=("haskell-array<0.3.0.2" 
          "haskell-bytestring<0.9.1.10"
          "haskell-cabal<1.10.1.0"
          "haskell-containers<0.4.0.0"
          "haskell-directory<1.1.0.0"
          "haskell-extensible-exceptions<0.1.1.2"
          "haskell-filepath<1.2.0.0"
          "haskell-haskell98<1.1.0.1"
          "haskell-hpc<0.5.0.6"
          "haskell-old-locale<1.0.0.2"
          "haskell-old-time<1.0.0.6"
          "haskell-pretty<1.0.1.2"
          "haskell-process<1.0.1.5"
          "haskell-random<1.0.0.3"
          "haskell-template-haskell<2.5.0.0"
          "haskell-time<1.2.0.3"
          "haskell-unix<2.4.2.0"
         )
options=(!strip 'docs')
install=$pkgname.install
source=("http://www.haskell.org/ghc/dist/$pkgver/ghc-$pkgver-src.tar.bz2"
        build.mk)
md5sums=('10bc5e9ae1b581404376efb85f260ff3'
         '5a3e0880c80b1dcecf779ff2e63a9c0d')

build() {
  cd $srcdir/$pkgname-$pkgver

  cp $srcdir/build.mk mk/build.mk

  ./configure \
    --prefix=/usr 
  make
}

package() {
  cd $srcdir/$pkgname-$pkgver
  make DESTDIR=$pkgdir install

  # Legal.
  install -Dm644 LICENSE $pkgdir/usr/share/licenses/$pkgname/license.txt
}