# Contributions from Arch: https://projects.archlinux.org/svntogit/community.git/tree/trunk?h=packages/kjots

pkgname=kjots
pkgver=5.0.2
pkgrel=1
pkgdesc="Note taker"
arch=('x86_64')
url="https://www.kde.org/applications/utilities/kjots/"
screenshot="https://www.kde.org/images/screenshots/kjots.png"
license=('GPL')
depends=(kcmutils kontactinterface akonadi-client akonadi-notes kdelibs4support kpimtextedit hicolor-icon-theme)
makedepends=(extra-cmake-modules kdoctools boost)
source=("http://download.kde.org/stable/$pkgname/$pkgver/$pkgname-$pkgver.tar.xz")
conflicts=(kdepim-kjots)
replaces=(kdepim-kjots)
provides=(kdepims-kjots)
install=$pkgname.install
md5sums=('296136e9860142596235d6d3f2c523e8')

prepare() {
  mkdir -p build
}

build() {
  cd build 
  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF 
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}